变量 当前用户名 = ""
// 程序入口功能
功能 _initial()
    发送文本消息("登录系统启动")
    mySql创建数据库()
结束

// 按下主按钮触发的功能方法
功能 _mainbutton()
    发送文本消息("你好mainbutton")
结束

// arg1在这里为用户名
// arg2在这里为密码
功能 _userlogin(token,arg1,arg2,out_ret)
    发送文本消息("arg1="&arg1&"  arg2="&arg2)
    如果(!效验用户(arg1,arg2))        
        返回 假    // 效验失败，不允许登录
    否则
        // 验证成功就直接登录
        返回 真
    结束
    返回 真
结束

功能 效验用户(name,pwd)
    // 根据mane与pwd一起查询
    变量 查询数据 = mySql查询所有信息ByNamePwd(name,pwd)
    如果(查询数据 != null)
        如果(查询数据[0]["islogin"] == "true")
            发送文本消息(name&"登录成功")
            返回 真
        否则
            发送文本消息(name&"未授权，不运行登录")
            返回 假
        结束
    否则
        mySql插入数据(name,pwd)
        //        sendconfigconfirm("授权","是否为下面的用户授权登录?","用户","待授权用户："& name,"yesno","待授权")
    结束    
    返回 假
结束


功能 _commoninterface(token,arg)
    变量 retArr = json转数组(arg)
    如果(是否数组(retArr))
        变量 指令类型 = retArr["command"]
        选择(指令类型)
            条件 "修改信息"
            如果(mySql修改用户信息(retArr["name"],retArr["sex"],retArr["old"],retArr["address"]))
                返回 "修改信息成功"
            否则                
                返回 "修改信息失败"
            结束
            
            条件 "获取信息"
            返回 mySql获取用户信息(retArr["name"])
        结束
    否则
        返回 "错误的数据格式"
    结束
结束

功能 _loadconfig()
    变量 arr = 数组("未授权用户","已授权用户","退出")
    变量 ret = 格式化单选框配置("UI_主界面",arr,"授权系统，查看未授权与已授权用户！","主界面")
    返回 ret 
结束

//交互界面的事件的枢纽,用户在app中点击所有交互界面中的控件,都会经过这个函数
功能 _submitconfig(id,value)
    发送文本消息("_submitconfig id:"&id&"  value:"&value)
    // 在主界面上的操作
    如果(id == "UI_主界面")
        如果(value == "未授权用户")
            返回 "config_未授权用户列表"
        否则如果(value == "已授权用户")
            返回 "config_已授权用户列表"
        否则
            返回 "exit"   // 退出交互界面
        结束 
    结束
    
    // 在未授权界面上的操作
    如果(id == "UI_未授权用户")
        当前用户名 = value
        返回 "config_是否授权当前用户"
    结束
    
    // 在确认授权界面上的操作
    如果(id == "UI_确认授权用户")
        如果(value == "yes")
            对当前用户授权()
            返回 "exit"
        否则
            返回 "config_未授权用户列表"
        结束        
    结束    
    
    // 未做任何处理就退出交互界面，避免出现错误页面
    返回 "exit"   // 退出交互界面
结束

功能 对当前用户授权()
    如果(mySql允许登录ByName(当前用户名))
        发送文本消息("对用户："&当前用户名&"授权成功")
    否则
        发送文本消息("对用户："&当前用户名&"授权失败")
    结束
结束

// 未授权用户列表界面
功能 config_未授权用户列表()
    //发送文本消息("config_未授权用户列表 11")
    变量 用户列表 = mySql查询所有信息()
    变量 待授权列表 = 数组()
    变量 size = 数组大小(用户列表)
    遍历(变量 i = 0; i < size; i++)
        如果(用户列表[i]["islogin"] == "false")
            关联数组追加元素(待授权列表,用户列表[i]["name"])
        结束
    结束    
    返回 格式化单选框配置("UI_未授权用户",待授权列表,"未授权的用户列表","未授权用户")
结束

// 已授权用户列表界面
功能 config_已授权用户列表()
    变量 用户列表 = mySql查询所有信息()
    变量 已授权列表 = 数组()
    变量 size = 数组大小(用户列表)
    遍历(变量 i = 0; i < size; i++)
        如果(用户列表[i]["islogin"] == "true")
            关联数组追加元素(已授权列表,用户列表[i]["name"])
        结束
    结束    
    返回 格式化单选框配置("UI_已授权用户",已授权列表,"已授权的用户列表","已授权用户")
结束

// 确定是否对选择的用户进行授权的界面
功能 config_是否授权当前用户()
    返回 格式化确认框配置("UI_确认授权用户","是否对当前选择的用户授权登录？",当前用户名)
结束